paddlepaddle--paddle/paddle/phi/kernels/gpu/linspace_kernel.cu

// Copyright (c) 2022 PaddlePaddle Authors. All Rights Reserved.
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
//     http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.

#include "paddle/phi/kernels/linspace_kernel.h"

#include "paddle/phi/backends/gpu/gpu_context.h"
#include "paddle/phi/backends/gpu/gpu_primitives.h"
#include "paddle/phi/core/kernel_registry.h"
#include "paddle/phi/core/tensor_utils.h"
#include "paddle/phi/kernels/funcs/math_function.h"

namespace phi {

template <typename T, typename StepT>
__global__ void LinspaceKernelInner(
    T start, T stop, StepT step, int64_t size, T* out) {
  int64_t index =
      static_cast<int64_t>(blockIdx.x) * static_cast<int64_t>(blockDim.x) +
      static_cast<int64_t>(threadIdx.x);

  for (; index < size; index += blockDim.x * gridDim.x) {
    if (index < size / 2) {
      out[index] = static_cast<T>(static_cast<StepT>(start) + step * index);
    } else {
      out[index] =
          static_cast<T>(static_cast<StepT>(stop) - step * (size - index - 1));
    }
  }
}

template <typename T>
__global__ void LinspaceKernelInner(
    T start, T stop, T step, int64_t size, T* out) {
  int64_t index =
      static_cast<int64_t>(blockIdx.x) * static_cast<int64_t>(blockDim.x) +
      static_cast<int64_t>(threadIdx.x);

  for (; index < size; index += blockDim.x * gridDim.x) {
    if (index < size / 2) {
      out[index] = start + step * static_cast<T>(index);
    } else {
      out[index] = stop - step * static_cast<T>(size - index - 1);
    }
  }
}

template <typename T>
__global__ void LinspaceSpecialKernel(T start, T* out) {
  out[0] = static_cast<T>(start);
}

template <typename T, typename Context>
T GetValueOfExpectedType(const Context& dev_ctx, const DenseTensor& x) {
  switch (x.dtype()) {
    case DataType::FLOAT32:
      return static_cast<T>(GetValue<float, Context>(dev_ctx, x));
    case DataType::FLOAT64:
      return static_cast<T>(GetValue<double, Context>(dev_ctx, x));
    case DataType::INT32:
      return static_cast<T>(GetValue<int32_t, Context>(dev_ctx, x));
    case DataType::INT64:
      return static_cast<T>(GetValue<int64_t, Context>(dev_ctx, x));
    case DataType::FLOAT16:
      return static_cast<T>(GetValue<float16, Context>(dev_ctx, x));
    case DataType::BFLOAT16:
      return static_cast<T>(GetValue<bfloat16, Context>(dev_ctx, x));
    case DataType::BOOL:
      return static_cast<T>(GetValue<bool, Context>(dev_ctx, x));
    case DataType::INT16:
      return static_cast<T>(GetValue<int16_t, Context>(dev_ctx, x));
    case DataType::UINT8:
      return static_cast<T>(GetValue<uint8_t, Context>(dev_ctx, x));
    default:
      PADDLE_THROW(common::errors::Unimplemented(
          "Data type (%s) is not supported when casting data type.",
          x.dtype()));
  }
}

inline bool isIntegralType(DataType t, bool includeBool) {
  bool isIntegral =
      (t == DataType::UINT8 || t == DataType::INT8 || t == DataType::UINT16 ||
       t == DataType::INT16 || t == DataType::UINT32 || t == DataType::INT32 ||
       t == DataType::UINT64 || t == DataType::INT64);

  return isIntegral || (includeBool && t == DataType::BOOL);
}

template <typename T, typename Context>
void LinspaceKernel(const Context& dev_ctx,
                    const DenseTensor& start,
                    const DenseTensor& stop,
                    const DenseTensor& number,
                    DataType dtype,
                    DenseTensor* out) {
  T start_value = GetValueOfExpectedType<T, Context>(dev_ctx, start);
  T stop_value = GetValueOfExpectedType<T, Context>(dev_ctx, stop);
  int64_t num = GetValueOfExpectedType<int64_t, Context>(dev_ctx, number);
  PADDLE_ENFORCE_GE(num,
                    0,
                    common::errors::InvalidArgument(
                        "The num of linspace op should be larger "
                        "than or equal to 0, but received num is %d",
                        num));

  out->Resize({num});
  T* out_data = dev_ctx.template Alloc<T>(out);
  if (num == 0) {
    return;
  }
  auto stream = dev_ctx.stream();
  if (num == 1) {
    LinspaceSpecialKernel<T><<<1, 1, 0, stream>>>(start_value, out_data);
  } else if (isIntegralType(dtype, true)) {
    int block = 512;
    int64_t grid_64 = (num + block - 1) / block;
    PADDLE_ENFORCE_LE_UINT32_MAX(grid_64, "grid");
    uint32_t grid = static_cast<uint32_t>(grid_64);

    float step =
        (static_cast<float>(stop_value) - static_cast<float>(start_value)) /
        (num - 1);
    LinspaceKernelInner<T, float><<<grid, block, 0, stream>>>(
        start_value, stop_value, step, num, out_data);
  } else {
    int block = 512;
    int64_t grid_64 = (num + block - 1) / block;
    PADDLE_ENFORCE_LE_UINT32_MAX(grid_64, "grid");
    uint32_t grid = static_cast<uint32_t>(grid_64);

    T step = (static_cast<T>(stop_value) - static_cast<T>(start_value)) /
             static_cast<T>(num - 1);
    LinspaceKernelInner<T><<<grid, block, 0, stream>>>(
        start_value, stop_value, step, num, out_data);
  }
}

}  // namespace phi

PD_REGISTER_KERNEL(linspace,
                   GPU,
                   ALL_LAYOUT,
                   phi::LinspaceKernel,
                   float,
                   int32_t,
                   int64_t,
                   double,
                   phi::float16,
                   phi::bfloat16) {
  kernel->InputAt(0).SetBackend(phi::Backend::ALL_BACKEND);
  kernel->InputAt(1).SetBackend(phi::Backend::ALL_BACKEND);
  kernel->InputAt(2).SetBackend(phi::Backend::ALL_BACKEND);
}