chore: import upstream snapshot with attribution

third_party/sqlite/BUILD.bazel

@@ -0,0 +1 @@
+# copybara:uncomment package(default_applicable_licenses = ["//tensorflow:license"])

third_party/sqlite/sqlite.BUILD

@@ -0,0 +1,63 @@
+# Description:
+#   sqlite3 is a serverless SQL RDBMS.
+
+licenses(["unencumbered"])  # Public Domain
+
+SQLITE_COPTS = [
+    "-DSQLITE_ENABLE_JSON1",
+    "-DHAVE_DECL_STRERROR_R=1",
+    "-DHAVE_STDINT_H=1",
+    "-DHAVE_INTTYPES_H=1",
+    "-D_FILE_OFFSET_BITS=64",
+    "-D_REENTRANT=1",
+] + select({
+    "@xla//xla/tsl:windows": [
+        "-DSQLITE_MAX_TRIGGER_DEPTH=100",
+    ],
+    "@xla//xla/tsl:macos": [
+        "-Os",
+        "-DHAVE_GMTIME_R=1",
+        "-DHAVE_LOCALTIME_R=1",
+        "-DHAVE_USLEEP=1",
+    ],
+    "//conditions:default": [
+        "-Os",
+        "-DHAVE_FDATASYNC=1",
+        "-DHAVE_GMTIME_R=1",
+        "-DHAVE_LOCALTIME_R=1",
+        "-DHAVE_POSIX_FALLOCATE=1",
+        "-DHAVE_USLEEP=1",
+    ],
+})
+
+# Production build of SQLite library that's baked into TensorFlow.
+cc_library(
+    name = "org_sqlite",
+    srcs = ["sqlite3.c"],
+    hdrs = [
+        "sqlite3.h",
+        "sqlite3ext.h",
+    ],
+    copts = SQLITE_COPTS,
+    defines = [
+        # This gets rid of the bloat of deprecated functionality. It
+        # needs to be listed here instead of copts because it's actually
+        # referenced in the sqlite3.h file.
+        "SQLITE_OMIT_DEPRECATED",
+    ],
+    linkopts = select({
+        "@xla//xla/tsl:windows": [],
+        "//conditions:default": [
+            "-ldl",
+            "-lpthread",
+        ],
+    }),
+    visibility = ["//visibility:public"],
+)
+
+# This is a Copybara sync helper for Google.
+py_library(
+    name = "python",
+    srcs_version = "PY3",
+    visibility = ["//visibility:public"],
+)

third_party/sqlite/workspace.bzl

@@ -0,0 +1,13 @@
+"""Loads the sqlite library, used by TF."""
+
+load("//third_party:repo.bzl", "tf_http_archive", "tf_mirror_urls")
+
+def repo():
+    tf_http_archive(
+        name = "org_sqlite",
+        build_file = "//third_party/sqlite:sqlite.BUILD",
+        sha256 = "9ad6d16cbc1df7cd55c8b55127c82a9bca5e9f287818de6dc87e04e73599d754",
+        strip_prefix = "sqlite-amalgamation-3500300",
+        system_build_file = "//third_party/systemlibs:sqlite.BUILD",
+        urls = tf_mirror_urls("https://www.sqlite.org/2025/sqlite-amalgamation-3500300.zip"),
+    )