wehub-resource-sync
100 lines
3.6 KiB
CMake
100 lines
3.6 KiB
CMake
# Copyright (c) 2026 PaddlePaddle Authors. All Rights Reserved.
|
|
#
|
|
# Licensed under the Apache License, Version 2.0 (the "License");
|
|
# you may not use this file except in compliance with the License.
|
|
# You may obtain a copy of the License at
|
|
#
|
|
# http://www.apache.org/licenses/LICENSE-2.0
|
|
#
|
|
# Unless required by applicable law or agreed to in writing, software
|
|
# distributed under the License is distributed on an "AS IS" BASIS,
|
|
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
# See the License for the specific language governing permissions and
|
|
# limitations under the License.
|
|
|
|
include(ExternalProject)
|
|
|
|
# Sleef external project configuration
|
|
# Sleef version: 3.6.1 is required because Paddle's
|
|
# paddle/phi/kernels/funcs/sleef_vectorized_math.h calls the unsuffixed AVX
|
|
# 256-bit symbols (e.g. Sleef_sinf8_u35, Sleef_sind4_u10, Sleef_expf8_u10),
|
|
# which are only generated by sleef <= 3.8 (HEADER_LIST contains AVX_).
|
|
# Newer sleef (>= 3.9) only exposes the *avx2 suffixed names.
|
|
set(SLEEF_TAG 3.6.1)
|
|
set(SOURCE_DIR ${PADDLE_SOURCE_DIR}/third_party/sleef)
|
|
set(SLEEF_SOURCE_DIR ${SOURCE_DIR})
|
|
set(SLEEF_PREFIX_DIR ${THIRD_PARTY_PATH}/sleef)
|
|
set(SLEEF_INSTALL_DIR ${THIRD_PARTY_PATH}/install/sleef)
|
|
|
|
# Pin sleef to the required tag inside the third_party submodule before build.
|
|
set(SLEEF_PATCH_COMMAND git checkout -- . && git checkout ${SLEEF_TAG})
|
|
|
|
set(SLEEF_INCLUDE_DIR
|
|
"${SLEEF_INSTALL_DIR}/include"
|
|
CACHE PATH "Sleef Include Directory" FORCE)
|
|
set(SLEEF_LIB_DIR
|
|
"${SLEEF_INSTALL_DIR}/lib"
|
|
CACHE PATH "Sleef Library Directory" FORCE)
|
|
set(SLEEF_LIBRARIES
|
|
"${SLEEF_INSTALL_DIR}/lib/${CMAKE_STATIC_LIBRARY_PREFIX}sleef${CMAKE_STATIC_LIBRARY_SUFFIX}"
|
|
CACHE FILEPATH "Sleef Library" FORCE)
|
|
|
|
if(CMAKE_C_COMPILER_ID MATCHES "GNU|Clang")
|
|
set(SLEEF_CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fPIC")
|
|
set(SLEEF_CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fPIC")
|
|
elseif(MSVC)
|
|
set(SLEEF_CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
|
|
set(SLEEF_CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
|
|
endif()
|
|
|
|
# For CMake >= 4.0.0, force policy compatibility for third-party sleef's CMake.
|
|
set(SLEEF_POLICY_ARGS "")
|
|
if(CMAKE_VERSION VERSION_GREATER_EQUAL "4.0.0")
|
|
message(
|
|
WARNING
|
|
"sleef: forcing CMake policy compatibility for CMake >= 4.0 (CMAKE_POLICY_VERSION_MINIMUM=3.5)"
|
|
)
|
|
set(SLEEF_POLICY_ARGS "-DCMAKE_POLICY_VERSION_MINIMUM=3.5")
|
|
endif()
|
|
|
|
set(SLEEF_CMAKE_ARGS
|
|
-DCMAKE_C_COMPILER=${CMAKE_C_COMPILER}
|
|
-DCMAKE_CXX_COMPILER=${CMAKE_CXX_COMPILER}
|
|
-DCMAKE_C_FLAGS=${SLEEF_CMAKE_C_FLAGS}
|
|
-DCMAKE_CXX_FLAGS=${SLEEF_CMAKE_CXX_FLAGS}
|
|
-DCMAKE_INSTALL_PREFIX=${SLEEF_INSTALL_DIR}
|
|
-DCMAKE_INSTALL_LIBDIR=${SLEEF_INSTALL_DIR}/lib
|
|
-DCMAKE_BUILD_TYPE=${THIRD_PARTY_BUILD_TYPE}
|
|
-DCMAKE_POSITION_INDEPENDENT_CODE=ON
|
|
-DBUILD_SHARED_LIBS=OFF
|
|
-DBUILD_TESTS=OFF
|
|
-DBUILD_DFT=OFF
|
|
-DBUILD_QUAD=OFF
|
|
-DENABLE_ALTDIV=OFF
|
|
-DENABLE_ALTSQRT=OFF
|
|
${EXTERNAL_OPTIONAL_ARGS}
|
|
${SLEEF_POLICY_ARGS})
|
|
|
|
ExternalProject_Add(
|
|
extern_sleef
|
|
${EXTERNAL_PROJECT_LOG_ARGS}
|
|
SOURCE_DIR ${SLEEF_SOURCE_DIR}
|
|
PREFIX ${SLEEF_PREFIX_DIR}
|
|
UPDATE_COMMAND ""
|
|
PATCH_COMMAND ${SLEEF_PATCH_COMMAND}
|
|
CMAKE_ARGS ${SLEEF_CMAKE_ARGS}
|
|
CMAKE_CACHE_ARGS
|
|
-DCMAKE_BUILD_TYPE:STRING=${THIRD_PARTY_BUILD_TYPE}
|
|
-DCMAKE_POSITION_INDEPENDENT_CODE:BOOL=ON
|
|
-DCMAKE_INSTALL_PREFIX:PATH=${SLEEF_INSTALL_DIR}
|
|
BUILD_BYPRODUCTS ${SLEEF_LIBRARIES})
|
|
|
|
message(STATUS "sleef library: ${SLEEF_LIBRARIES}")
|
|
include_directories(${SLEEF_INCLUDE_DIR})
|
|
|
|
add_library(sleef STATIC IMPORTED GLOBAL)
|
|
set_target_properties(sleef PROPERTIES IMPORTED_LOCATION ${SLEEF_LIBRARIES})
|
|
add_dependencies(sleef extern_sleef)
|
|
|
|
set(SLEEF_FOUND TRUE)
|