// Copyright (c) 2022 PaddlePaddle Authors. All Rights Reserved.
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
//     http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.

#include "paddle/phi/kernels/logspace_kernel.h"

#include "paddle/common/enforce.h"
#include "paddle/phi/backends/gpu/gpu_context.h"
#include "paddle/phi/common/amp_type_traits.h"
#include "paddle/phi/core/kernel_registry.h"
#include "paddle/phi/core/tensor_utils.h"
#include "paddle/phi/kernels/funcs/data_type_transform.h"
#include "paddle/phi/kernels/funcs/math_function.h"

namespace phi {

template <typename T>
__global__ void LogspaceKernelInner(
    T start, T stop, double step, T base, int64_t size, T* out) {
  using MT = typename MPTypeTrait<T>::Type;
  MT mt_start = static_cast<MT>(start);
  MT mt_stop = static_cast<MT>(stop);
  MT mt_base = static_cast<MT>(base);

  int64_t index =
      static_cast<int64_t>(blockIdx.x) * static_cast<int64_t>(blockDim.x) +
      static_cast<int64_t>(threadIdx.x);

  for (; index < size; index += blockDim.x * gridDim.x) {
    if (index < size / 2) {
      out[index] =
          static_cast<T>(pow(static_cast<double>(mt_base),
                             static_cast<double>(mt_start + step * index)));
    } else {
      out[index] = static_cast<T>(
          pow(static_cast<double>(mt_base),
              static_cast<double>(mt_stop - step * (size - index - 1))));
    }
  }
}

template <typename T>
__global__ void LogspaceSpecialKernel(T start, T base, T* out) {
  using MT = typename MPTypeTrait<T>::Type;
  MT mt_start = static_cast<MT>(start);
  MT mt_base = static_cast<MT>(base);

  out[0] = static_cast<T>(
      pow(static_cast<double>(mt_base), static_cast<double>(mt_start)));
}

template <typename T, typename Context>
void LogspaceKernel(const Context& dev_ctx,
                    const DenseTensor& start,
                    const DenseTensor& stop,
                    const DenseTensor& number,
                    const DenseTensor& base,
                    DataType dtype,
                    DenseTensor* out) {
  using MT = typename MPTypeTrait<T>::Type;

  auto start_t = funcs::TransDataType(dev_ctx, start, dtype);
  auto stop_t = funcs::TransDataType(dev_ctx, stop, dtype);
  auto base_t = funcs::TransDataType(dev_ctx, base, dtype);

  DenseTensor n_start;
  DenseTensor n_stop;
  DenseTensor n_num;
  DenseTensor n_base;
  Copy(dev_ctx, start_t, CPUPlace(), false, &n_start);
  T start_data = n_start.data<T>()[0];
  Copy(dev_ctx, stop_t, CPUPlace(), false, &n_stop);
  T stop_data = n_stop.data<T>()[0];
  Copy(dev_ctx, number, CPUPlace(), false, &n_num);
  int64_t num = static_cast<int64_t>(n_num.data<int32_t>()[0]);
  Copy(dev_ctx, base_t, CPUPlace(), false, &n_base);
  T base_data = n_base.data<T>()[0];

  MT mt_start_data = static_cast<MT>(start_data);
  MT mt_stop_data = static_cast<MT>(stop_data);

  PADDLE_ENFORCE_GT(
      num,
      0,
      common::errors::InvalidArgument("The num of logspace op should be larger "
                                      "than 0, but received num is %d",
                                      num));

  out->Resize({num});
  T* out_data = dev_ctx.template Alloc<T>(out);

  double step = 0;
  auto stream = dev_ctx.stream();
  int block = 512;
  int64_t grid_64 = (num + block - 1) / block;
  PADDLE_ENFORCE_LE_UINT32_MAX(grid_64, "grid");
  uint32_t grid = static_cast<uint32_t>(grid_64);
  if (num != 1) {
    step = (static_cast<double>(mt_stop_data - mt_start_data)) / (num - 1);
    LogspaceKernelInner<T><<<grid, block, 0, stream>>>(
        start_data, stop_data, step, base_data, num, out_data);
  } else {
    LogspaceSpecialKernel<T>
        <<<grid, block, 0, stream>>>(start_data, base_data, out_data);
  }
}

}  // namespace phi

PD_REGISTER_KERNEL(logspace,
                   GPU,
                   ALL_LAYOUT,
                   phi::LogspaceKernel,
                   float,
                   int32_t,
                   int64_t,
                   double,
                   phi::float16,
                   phi::bfloat16) {}